通過這個簡單的遊戲學習 Tcl/Tk 和 Wish

以下是一個簡單的編程項目，能夠幫助你開始學習 Tcl/Tk。

探索 Tcl/Tk 的基礎構造，包括用戶輸入、輸出、變數、條件評估、簡單函數和基礎事件驅動編程。

我寫這篇文章的初衷源於我想更深入地利用基於 Tcl 的 Expect。這讓我寫下了以下兩篇文章：通過編寫一個簡單的遊戲學習 Tcl 和 通過編寫一個簡單的遊戲學習 Expect。

我進行了一些 Ansible 自動化工作，逐漸積累了一些本地腳本。有些腳本我頻繁使用，以至於以下循環操作變得有些煩人：

• 打開終端
• 使用 cd 命令跳轉至合適的目錄
• 輸入一條帶有若干選項的長命令啟動所需的自動化流程

我日常使用的是 macOS。實際上我更希望有一個菜單項或者一個圖標，能夠彈出一個簡單的界面接受參數並執行我需要的操作，這就像在 Linux 的 KDE 中一樣。

經典的 Tcl 類書籍都包含了關於流行的 Tk 擴展的文檔。既然我已經深入研究了這個主題，我嘗試著對其（即 wish）進行編程。

雖然我並非一名 GUI 或者前端開發者，但我發現 Tcl/Tk 腳本編寫的方式相當直接易懂。我很高興能重新審視這個 UNIX 歷史的古老且穩定的部分，這種技術在現代平台上依然有用且可用。

安裝 Tcl/Tk

對於 Linux 系統，你可以按照下面的方式安裝：

$ sudo dnf install tcl
$ which wish
/bin/wish

而在 macOS 上，你可以通過 Homebrew 來安裝最新版的 Tcl/Tk：

$ brew install tcl-tk
$ which wish
/usr/local/bin/wish

編程理念

許多編寫遊戲的教程都會介紹到典型的編程語言結構，如循環、條件判斷、變數、函數和過程等等。

在此篇文章中，我想要介紹的是 事件驅動編程。當你的程序使用事件驅動編程，它會進入一個特殊的內置循環，等待特定的事件發生。當這個特定的事件發生時，相應的代碼就會被觸發，產生預期的結果。

這些事件可以包括鍵盤輸入、滑鼠移動、點擊按鈕、定時器觸發，甚至是任何你的電腦硬體能夠識別的事件（可能來自特殊的設備）。你的程序中的代碼決定了用戶看到了什麼，以及程序需要監聽什麼輸入，當這些輸入被接收後程序會怎麼做，然後進入事件循環等待輸入。

這篇文章的理念並沒有脫離我之前的 Tcl 文章太遠。這裡最大的不同在於用 GUI 設置和用於處理用戶輸入的事件循環替代了循環結構。其他的不同則是 GUI 開發需要採取的各種方式來製作一個可用的用戶界面。在採用 Tk GUI 開發的時候，你需要了解兩個基礎的概念： 部件 widget 和 幾何管理器 geometry manager 。

部件是構成可視化元素的 UI 元素，通過這些元素用戶可以與程序進行交互。這其中包括了按鈕、文本區域、標籤和文本輸入框。部件還包括了一些選項選擇，如菜單、複選框、單選按鈕等。最後，部件也包括了其他的可視化元素，如邊框和線性分隔符。

幾何管理器在放置部件在顯示窗口中的位置上扮演著至關重要的角色。有一些不同的幾何管理器可以供你使用。在這篇文章中，我主要使用了 grid 幾何來讓部件在整齊的行中進行布局。我會在這篇文章的結尾地方解釋一些幾何管理器的不同之處。

用 wish 進行猜數字遊戲

這個示例遊戲代碼與我其他文章中的示例有所不同，我將它分解為若干部分以方便解釋。

首先創建一個基本的可執行腳本 numgame.wish ：

$ touch numgame.wish
$ chmod 755 numgame.wish

使用你喜歡的文本編輯器打開此文件，輸入下列代碼的第一部分：

#!/usr/bin/env wish
set LOW 1
set HIGH 100
set STATUS ""
set GUESS ""
set num [expr round(rand()*100)]

第一行定義了該腳本將通過 wish 執行。接下來，創建了幾個全局變數。這裡我使用全部大寫字母定義全局變數，這些變數將綁定到跟蹤這些值的窗口小部件（LOW、HIGH等等）。

全局變數 num 是遊戲玩家要猜測的隨機數值，這個值是通過 Tcl 的命令執行得到並保存到變數中的：

proc Validate {var} {
    if { [string is integer $var] } {
        return 1
    }
    return 0
}

這是一個驗證用戶輸入的特殊函數，它只接受整數並拒絕其他所有類型的輸入：

proc check_guess {guess num} {
    global STATUS LOW HIGH GUESS

    if { $guess < $LOW } {
        set STATUS "What?"
    } elseif { $guess > $HIGH } {
        set STATUS "Huh?"
    } elseif { $guess < $num } {
        set STATUS "Too low!"
        set LOW $guess
    } elseif { $guess > $num } {
        set STATUS "Too high!"
        set HIGH $guess
    } else {
        set LOW $guess
        set HIGH $guess
        set STATUS "That&apos;s Right!"
        destroy .guess .entry
        bind all <Return> {.quit invoke}
    }

    set GUESS ""
}

這是主要的猜數邏輯循環。global 語句讓我們能夠修改在文件開頭創建的全局變數（關於此主題後面將會有更多解釋）。這個條件判斷尋找入力範圍在 1 至 100 之外以及已經被用戶猜過的值。有效的猜測和隨機值進行比較。LOW 和 HIGH 的猜測會被追蹤，作為 UI 中的全局變數進行報告。在每一步，全局 STATUS 變數都會被更新，這個狀態信息會自動在 UI 中顯示。

對於正確的猜測，destroy 語句會移除 「Guess」 按鈕以及輸入窗口，並重新綁定回車鍵，以激活 「Quit」 按鈕。

最後的語句 set GUESS "" 用於在下一個猜測之前清空輸入窗口。

label .inst -text "Enter a number between: "
label .low -textvariable LOW
label .dash -text "-"
label .high -textvariable HIGH
label .status -text "Status:"
label .result -textvariable STATUS
button .guess -text "Guess" -command { check_guess $GUESS $num }
entry .entry -width 3 -relief sunken -bd 2 -textvariable GUESS -validate all 
    -validatecommand { Validate %P }
focus .entry
button .quit -text "Quit" -command { exit }
bind all <Return> {.guess invoke}

這是設置用戶界面的部分。前六個標籤語句在你的 UI 上創建了不同的文本展示元素，-textvariable 選項監控給定的變數，並自動更新標籤的值，這展示了全局變數 LOW、HIGH、STATUS 的綁定。

button 行創建了 「Guess」 和 「Quit」 按鈕， -command 選項設定了當按鈕被按下時要執行的操作。按下 「Guess」 按鈕執行了上面的 check_guess 函數以檢查用戶輸入的值。

entry 部件更有趣。它創建了一個三字元寬的輸入框，並將輸入綁定到 GUESS 全局變數。它還通過 -validatecommand 選項設置了驗證，阻止輸入部件接收除數字以外的任何內容。

focus 命令是用戶界面的一項改進，使程序啟動時輸入部件處於激活狀態。沒有此命令，你需要先點擊輸入部件才可以輸入。

bind 命令允許你在按下回車鍵時自動點擊 「Guess」 按鈕。如果你記得 check_guess 中的內容，猜測正確之後會重新綁定回車鍵到 「Quit」 按鈕。

最後，這部分設定了圖形用戶界面的布局：

grid .inst
grid .low .dash .high
grid .status .result
grid .guess .entry
grid .quit

grid 幾何管理器被逐步調用，以逐漸構建出預期的用戶體驗。它主要設置了五行部件。前三行是顯示不同值的標籤，第四行是 「Guess」 按鈕和 entry 部件，最後是 「Quit」 按鈕。

程序到此已經初始化完畢，wish shell 進入事件循環，等待用戶輸入整數並按下按鈕。基於其在被監視的全局變數中找到的變化，它會更新標籤。

注意，輸入游標開始就在輸入框中，而且按下回車鍵將調用適當且可用的按鈕。

這只是一個初級的例子，Tcl/Tk 有許多可以讓間隔、字體、顏色和其他用戶界面方面更具有吸引力的選項，這超出了本文中簡單 UI 的示例。

運行這個應用，你可能會注意到這些部件看起來並不很精緻或現代。這是因為我正在使用原始的經典部件集，它們讓人回憶起 X Windows Motif 的時代。不過，還有一些默認的部件擴展，被稱為主題部件，它們可以讓你的應用程序有更現代、更精緻的外觀和感覺。

啟動遊戲！

保存文件之後，在終端中運行它：

$ ./numgame.wish

在這種情況下，我無法給出控制台的輸出，因此這裡有一個動畫 GIF 來展示如何玩這個遊戲：

進一步了解 Tcl

Tcl 支持命名空間的概念，所以在這裡使用的變數並不必須是全局的。你可以把綁定的部件變數組織進不同的命名空間。對於像這樣的簡單程序，可能並不太需要這麼做。但對於更大規模的項目，你可能會考慮這種方法。

proc check_guess 函數體內有一行 global 代碼我之前沒有解釋。在 Tcl 中，所有變數都按值傳遞，函數體內引用的變數的範圍是局部的。在這個情況下，我希望修改的是全局變數，而不是局部範圍的版本。Tcl 提供了許多方法來引用變數，在執行堆棧的更高級別執行代碼。在一些情況下，像這樣的簡單引用可能帶來一些複雜性和錯誤，但是調用堆棧的操作非常有力，允許 Tcl 實現那些在其他語言中實現起來可能較為複雜的新的條件和循環結構。

最後，在這篇文章中，我沒有提到幾何管理器，它們用於以特定的順序展示部件。只有被某種幾何管理器管理的部件才能顯示在屏幕上。grid 管理器相當簡潔，它按照從左到右的方式放置部件。我使用了五個 grid 定義來創建了五行。另外還有兩個幾何管理器：place 和 pack。pack 管理器將部件圍繞窗口邊緣排列，而 place 管理器允許固定部件的位置。除這些幾何管理器外，還有一些特殊的部件，如 canvas ，text 和 panedwindow，它們可以容納並管理其他部件。你可以在經典的 Tcl/Tk 參考指南，以及 Tk 命令 文檔頁上找到這些部件的全面描述。

繼續學習編程

Tcl 和 Tk 提供了一個簡單有效的方法來構建圖形用戶界面和事件驅動應用程序。這個簡單的猜數遊戲只是你能用這些工具做到的事情的起點。通過繼續學習和探索 Tcl 和 Tk，你可以打開構建強大且用戶友好的應用程序的無數可能性。繼續嘗試，繼續學習，看看你新習得的 Tcl 和 Tk 技能能帶你到哪裡。

（題圖：MJ/40621c50-6577-4033-9f3c-8013bd0286f1）

via: https://opensource.com/article/23/4/learn-tcltk-wish-simple-game

作者：James Farrell 選題：lkxed 譯者：ChatGPT 校對：wxy

本文由 LCTT 原創編譯，Linux中國 榮譽推出

本文轉載來自 Linux 中國: https://github.com/Linux-CN/archive