計算機實驗室之樹莓派：課程 4 OK04

OK04 課程在 OK03 的基礎上進行構建，它教你如何使用定時器讓 OK 或 ACT LED 燈按精確的時間間隔來閃爍。假設你已經有了 課程 3：OK03 的操作系統，我們將以它為基礎來構建。

1、一個新設備

定時器是樹莓派保持時間的唯一方法。大多數計算機都有一個電池供電的時鐘，這樣當計算機關機後仍然能保持時間。

到目前為止，我們僅看了樹莓派硬體的一小部分，即 GPIO 控制器。我只是簡單地告訴你做什麼，然後它會發生什麼事情。現在，我們繼續看定時器，並繼續帶你去了解它的工作原理。

和 GPIO 控制器一樣，定時器也有地址。在本案例中，定時器的基地址在 20003000 ₁₆。閱讀手冊我們可以找到下面的表：

表 1.1 GPIO 控制器寄存器

這個表只告訴我們一部分內容，在手冊中描述了更多的欄位。手冊上解釋說，定時器本質上是按每微秒將計數器遞增 1 的方式來運行。每次它是這樣做的，它將計數器的低 32 位（4 位元組）與 4 個比較器寄存器進行比較，如果匹配它們中的任何一個，它更新 Control/Status 以反映出其中有一個是匹配的。

關於 位 bit 、 位元組 byte 、 位欄位 bit field 、以及數據大小的更多內容如下：

一個位是一個單個的二進位數的名稱。你可能還記得，一個單個的二進位數既可能是一個 1，也可能是一個 0。

一個位元組是一個 8 位集合的名稱。由於每個位可能是 1 或 0 這兩個值的其中之一，因此，一個位元組有 2 ⁸ = 256 個不同的可能值。我們一般解釋一個位元組為一個介於 0 到 255（含）之間的二進位數。

一個位欄位是解釋二進位的另一種方式。二進位可以解釋為許多不同的東西，而不僅僅是一個數字。一個位欄位可以將二進位看做為一系列的 1（開） 或 0（關）的開關。對於每個小開關，我們都有一個意義，我們可以使用它們去控制一些東西。我們已經遇到了 GPIO 控制器使用的位欄位，使用它設置一個針腳的開或關。位為 1 時 GPIO 針腳將準確地打開或關閉。有時我們需要更多的選項，而不僅僅是開或關，因此我們將幾個開關組合到一起，比如 GPIO 控制器的函數設置（如上圖），每 3 位為一組控制一個 GPIO 針腳的函數。

我們的目標是實現一個函數，這個函數能夠以一個時間數量為輸入來調用它，這個輸入的時間數量將作為等待的時間，然後返回。想一想如何去做，想想我們都擁有什麼。

我認為這將有兩個選擇：

1. 從計數器中讀取一個值，然後保持分支返回到相同的代碼，直到計數器的等待時間數量大於它。
2. 從計數器中讀取一個值，加上要等待的時間數量，將它保存到比較器寄存器，然後保持分支返回到相同的代碼處，直到 Control / Status 寄存器更新。

這兩種策略都工作的很好，但在本教程中，我們將只實現第一個。原因是比較器寄存器更容易出錯，因為在增加等待時間並保存它到比較器的寄存器期間，計數器可能已經增加了，並因此可能會不匹配。如果請求的是 1 微秒（或更糟糕的情況是 0 微秒）的等待，這樣可能導致非常長的意外延遲。

像這樣存在被稱為「並發問題」的問題，並且幾乎無法解決。

2、實現

我將把這個創建完美的等待方法的挑戰基本留給你。我建議你將所有與定時器相關的代碼都放在一個名為 systemTimer.s 的文件中（理由很明顯）。關於這個方法的複雜部分是，計數器是一個 8 位元組值，而每個寄存器僅能保存 4 位元組。所以，計數器值將分到 2 個寄存器中。

大型的操作系統通常使用等待函數來抓住機會在後台執行任務。

下列的代碼塊是一個示例。

ldrd r0,r1,[r2,#4]

ldrd regLow,regHigh,[src,#val] 從 src 中的數加上 val 之和的地址載入 8 位元組到寄存器 regLow 和 regHigh 中。

上面的代碼中你可以發現一個很有用的指令是 ldrd。它載入 8 位元組的內存到兩個寄存器中。在本案例中，這 8 位元組內存從寄存器 r2 中的地址 + 4 開始，將被複制進寄存器 r0 和 r1。這種安排的稍微複雜之處在於 r1 實際上只持有了高位 4 位元組。換句話說就是，如果如果計數器的值是 999,999,999,999 ₁₀ = 1110100011010100101001010000111111111111 ₂ ，那麼寄存器 r1 中只有 11101000 ₂，而寄存器 r0 中則是 11010100101001010000111111111111 ₂。

實現它的更明智的方式應該是，去計算當前計數器值與來自方法啟動後的那一個值的差，然後將它與要求的等待時間數量進行比較。除非恰好你希望的等待時間是佔用 8 位元組的，否則上面示例中寄存器 r1 中的值將會丟棄，而計數器僅需要使用低位 4 位元組。

當等待開始時，你應該總是確保使用大於比較，而不是使用等於比較，因為如果你嘗試去等待一個時間，而這個時間正好等於方法開始的時間與結束的時間之差，那麼你就錯過這個值而永遠等待下去。

如果你不明白如何編寫等待函數的代碼，可以參考下面的指南。

借鑒 GPIO 控制器的創意，第一個函數我們應該去寫如何取得系統定時器的地址。示例如下：

.globl GetSystemTimerBase
GetSystemTimerBase:
ldr r0,=0x20003000
mov pc,lr

另一個被證明非常有用的函數是返回在寄存器 r0 和 r1 中的當前計數器值：

.globl GetTimeStamp
GetTimeStamp:
push {lr}
bl GetSystemTimerBase
ldrd r0,r1,[r0,#4]
pop {pc}

這個函數簡單地使用了 GetSystemTimerBase 函數，並像我們前面學過的那樣，使用 ldrd 去載入當前計數器值。

現在，我們可以去寫我們的等待方法的代碼了。首先，在該方法啟動後，我們需要知道計數器值，我們可以使用 GetTimeStamp 來取得。

delay .req r2
mov delay,r0
push {lr}
bl GetTimeStamp
start .req r3
mov start,r0

這個代碼複製了我們的方法的輸入，將延遲時間的數量放到寄存器 r2 中，然後調用 GetTimeStamp，這個函數將會返回寄存器 r0 和 r1 中的當前計數器值。接著複製計數器值的低位 4 位元組到寄存器 r3 中。

接下來，我們需要計算當前計數器值與讀入的值的差，然後持續這樣做，直到它們的差至少是 delay 的大小為止。

loop$:

bl GetTimeStamp
elapsed .req r1
sub elapsed,r0,start
cmp elapsed,delay
.unreq elapsed
bls loop$

這個代碼將一直等待，一直到等待到傳遞給它的時間數量為止。它從計數器中讀取數值，減去最初從計數器中讀取的值，然後與要求的延遲時間進行比較。如果過去的時間數量小於要求的延遲，它切換回 loop$。

.unreq delay
.unreq start
pop {pc}

代碼完成後，函數返回。

3、另一個閃燈程序

你一旦明白了等待函數的工作原理，修改 main.s 去使用它。修改各處 r0 的等待設置值為某個很大的數量（記住它的單位是微秒），然後在樹莓派上測試。如果函數不能正常工作，請查看我們的排錯頁面。

如果正常工作，恭喜你學會控制另一個設備了，會使用它，則時間由你控制。在下一節課程中，我們將完成 OK 系列課程的最後一節 課程 5：OK05，我們將使用我們已經學習過的知識讓 LED 按我們的模式進行閃爍。

via: https://www.cl.cam.ac.uk/projects/raspberrypi/tutorials/os/ok04.html

作者：Robert Mullins 選題：lujun9972 譯者：qhwdw 校對：wxy

本文由 LCTT 原創編譯，Linux中國 榮譽推出

本文轉載來自 Linux 中國: https://github.com/Linux-CN/archive