計算機實驗室之樹莓派：課程 10 輸入01

歡迎進入輸入課程系列。在本系列，你將會學會如何使用鍵盤接收輸入給樹莓派。我們將會從揭示輸入開始本課，然後轉向更傳統的文本提示符。

這是第一堂輸入課，會教授一些關於驅動和鏈接的理論，同樣也包含鍵盤的知識，最後以在屏幕上顯示文本結束。

1、開始

希望你已經完成了 OK 系列課程，這會對你完成屏幕系列課程很有幫助。很多 OK 課程上的文件會被使用而不會做解釋。如果你沒有這些文件，或者希望使用一個正確的實現，可以從該堂課的下載頁下載模板。如果你使用你自己的實現，請刪除調用了 SetGraphicsAddress 之後全部的代碼。

2、USB

如你所知，樹莓派 B 型有兩個 USB 介面，通常用來連接一個滑鼠和一個鍵盤。這是一個非常好的設計決策，USB 是一個非常通用的介面，很多種設備都可以使用它。這就很容易為它設計新外設，很容易為它編寫設備驅動，而且通過 USB 集線器可以非常容易擴展。還能更好嗎？當然是不能，實際上對一個操作系統開發者來說，這就是我們的噩夢。USB 標準太大了。我是說真的，在你思考如何連接設備之前，它的文檔將近 700 頁。

USB 標準的設計目的是通過複雜的軟體來簡化硬體交互。

我和很多愛好操作系統的開發者談過這些，而他們全部都說幾句話：不要抱怨。「實現這個需要花費很久時間」，「你不可能寫出關於 USB 的教程」，「收益太小了」。在很多方面，他們是對的，我不可能寫出一個關於 USB 標準的教程，那得花費幾周時間。我同樣不能教授如何為全部所有的設備編寫外設驅動，所以使用自己寫的驅動是沒什麼用的。然而，即便不能做到最好，我仍然可以獲取一個正常工作的 USB 驅動，拿一個鍵盤驅動，然後教授如何在操作系統中使用它們。我開始尋找可以運行在一個甚至不知道文件是什麼的操作系統的自由驅動，但是我一個都找不到，它們都太高層了，所以我嘗試寫一個。大家說的都對，這耗費了我幾周時間。然而我可以高興的說我做的這些工作沒有獲取操作系統以外的幫助，並且可以和滑鼠和鍵盤通信。這絕不是完整的、高效的，或者正確的，但是它能工作。驅動是以 C 編寫的，而且有興趣的可以在下載頁找到全部源代碼。

所以，這一個教程不會是 USB 標準的課程（一點也沒有）。實際上我們將會看到如何使用其他人的代碼。

3、鏈接

既然我們要引進外部代碼到操作系統，我們就需要談一談 鏈接 linking 。鏈接是一種過程，可以在程序或者操作系統中鏈接函數。這意味著當一個程序生成之後，我們不必要編寫每一個函數（幾乎可以肯定，實際上並非如此）。鏈接就是我們做的用來把我們程序和別人代碼中的函數連結在一起。這個實際上已經在我們的操作系統進行了，因為鏈接器把所有不同的文件鏈接在一起，每個都是分開編譯的。

鏈接允許我們製作可重用的代碼庫，所有人都可以在他們的程序中使用。

有兩種鏈接方式：靜態和動態。靜態鏈接就像我們在製作自己的操作系統時進行的。鏈接器找到全部函數的地址，然後在鏈接結束前，將這些地址都寫入代碼中。動態鏈接是在程序「完成」之後。當程序載入後，動態鏈接器檢查程序，然後在操作系統的庫找到所有不在程序里的函數。這就是我們的操作系統最終應該能夠完成的一項工作，但是現在所有東西都將是靜態鏈接的。

程序經常調用調用庫，這些庫會調用其它的庫，直到最終調用了我們寫的操作系統的庫。

我編寫的 USB 驅動程序適合靜態編譯。這意味著我給你的是每個文件的編譯後的代碼，然後鏈接器找到你的代碼中的那些沒有實現的函數，就將這些函數鏈接到我的代碼。在本課的 下載頁 是一個 makefile 和我的 USB 驅動，這是接下來需要的。下載並使用這個 makefile 替換你的代碼中的 makefile， 同事將驅動放在和這個 makefile 相同的文件夾。

4、鍵盤

為了將輸入傳給我們的操作系統，我們需要在某種程度上理解鍵盤是如何實際工作的。鍵盤有兩種按鍵：普通鍵和修飾鍵。普通按鍵是字母、數字、功能鍵，等等。它們構成了鍵盤上幾乎全部按鍵。修飾鍵是多達 8 個的特殊鍵。它們是左 shift、右 shift、左 ctrl、右 ctrl、左 alt、右 alt、左 GUI 和右 GUI。鍵盤可以檢測出所有的組合中那個修飾鍵被按下了，以及最多 6 個普通鍵。每次一個按鈕變化了（例如，是按下了還是釋放了），鍵盤就會報告給電腦。通常，鍵盤也會有 3 個 LED 燈，分別指示大寫鎖定，數字鍵鎖定，和滾動鎖定，這些都是由電腦控制的，而不是鍵盤自己。鍵盤也可能有更多的燈，比如電源、靜音，等等。

對於標準 USB 鍵盤，有一個按鍵值的表，每個鍵盤按鍵都一個唯一的數字，每個可能的 LED 也類似。下面的表格列出了前 126 個值。

表 4.1 USB 鍵盤值

完全列表可以在HID 頁表 1.12的 53 頁，第 10 節找到。

5、車輪後的螺母

通常，當你使用其他人的代碼，他們會提供一份自己代碼的總結，描述代碼都做了什麼，粗略介紹了是如何工作的，以及什麼情況下會出錯。下面是一個使用我的 USB 驅動的相關步驟要求。

這些總結和代碼的描述組成了一個 API - 應用程序產品介面。

表 5.1 CSUD 中和鍵盤相關的函數

有幾種方法返回「返回值」。這些都是 C 代碼的老生常談了，就是用數字代表函數調用發生了什麼。通常情況， 0 總是代表操作成功。下面的是驅動用到的返回值。

返回值是一種處理錯誤的簡單方法，但是通常更優雅的解決途徑會出現於更高層次的代碼。

表 5.2 - CSUD 返回值

驅動的通常用法如下：

1. 調用 UsbInitialise
2. 調用 UsbCheckForChange
3. 調用 KeyboardCount
4. 如果返回 0，重複步驟 2。
5. 針對你支持的每個鍵盤：
   1. 調用 KeyboardGetAddress
   2. 調用 KeybordGetKeyDownCount
   3. 針對每個按下的按鍵：
      1. 檢查它是否已經被按下了
      2. 保存按下的按鍵
   4. 針對每個保存的按鍵：
      1. 檢查按鍵是否被釋放了
      2. 如果釋放了就刪除
6. 根據按下/釋放的案件執行操作
7. 重複步驟 2

最後，你可以對鍵盤做所有你想做的任何事了，而這些方法應該允許你訪問鍵盤的全部功能。在接下來的兩節課，我們將會著眼於完成文本終端的輸入部分，類似於大部分的命令行電腦，以及命令的解釋。為了做這些，我們將需要在更有用的形式下得到一個鍵盤輸入。你可能注意到我的驅動是（故意的）沒有太大幫助，因為它並沒有方法來判斷是否一個按鍵剛剛按下或釋放了，它只有方法來判斷當前那個按鍵是按下的。這就意味著我們需要自己編寫這些方法。

6、可用更新

首先，讓我們實現一個 KeyboardUpdate 方法，檢查第一個鍵盤，並使用輪詢方法來獲取當前的輸入，以及保存最後一個輸入來對比。然後我們可以使用這個數據和其它方法來將掃描碼轉換成按鍵。這個方法應該按照下面的說明準確操作：

重複檢查更新被稱為「輪詢」。這是針對驅動 IO 中斷而言的，這種情況下設備在準備好後會發一個信號。

1. 提取一個保存好的鍵盤地址（初始值為 0）。
2. 如果不是 0 ，進入步驟 9.
3. 調用 UsbCheckForChange 檢測新鍵盤。
4. 調用 KeyboardCount 檢測有幾個鍵盤在線。
5. 如果返回 0，意味著沒有鍵盤可以讓我們操作，只能退出了。
6. 調用 KeyboardGetAddress 參數是 0，獲取第一個鍵盤的地址。
7. 保存這個地址。
8. 如果這個值是 0，那麼退出，這裡應該有些問題。
9. 調用 KeyboardGetKeyDown 6 次，獲取每次按鍵按下的值並保存。
10. 調用 KeyboardPoll
11. 如果返回值非 0，進入步驟 3。這裡應該有些問題（比如鍵盤斷開連接）。

要保存上面提到的值，我們將需要下面 .data 段的值。

.section .data
.align 2
KeyboardAddress:
.int 0
KeyboardOldDown:
.rept 6
.hword 0
.endr

.hword num 直接將半字的常數插入文件。

.rept num [commands] .endr 複製 `commands` 命令到輸出 num 次。

試著自己實現這個方法。對此，我的實現如下：

1、我們載入鍵盤的地址。

.section .text
.globl KeyboardUpdate
KeyboardUpdate:
push {r4,r5,lr}

kbd .req r4
ldr r0,=KeyboardAddress
ldr kbd,[r0]

2、如果地址非 0，就說明我們有一個鍵盤。調用 UsbCheckForChanges 慢，所以如果一切正常，我們要避免調用這個函數。

teq kbd,#0
bne haveKeyboard$

3、如果我們一個鍵盤都沒有，我們就必須檢查新設備。

getKeyboard$:
bl UsbCheckForChange

4、如果有新鍵盤添加，我們就會看到這個。

bl KeyboardCount

5、如果沒有鍵盤，我們就沒有鍵盤地址。

teq r0,#0
ldreq r1,=KeyboardAddress
streq r0,[r1]
beq return$

6、讓我們獲取第一個鍵盤的地址。你可能想要支持更多鍵盤。

mov r0,#0
bl KeyboardGetAddress

7、保存鍵盤地址。

ldr r1,=KeyboardAddress
str r0,[r1]

8、如果我們沒有鍵盤地址，這裡就沒有其它活要做了。

teq r0,#0
beq return$
mov kbd,r0

9、循環查詢全部按鍵，在 KeyboardOldDown 保存下來。如果我們詢問的太多了，返回 0 也是正確的。

saveKeys$:
  mov r0,kbd
  mov r1,r5
  bl KeyboardGetKeyDown

  ldr r1,=KeyboardOldDown
  add r1,r5,lsl #1
  strh r0,[r1]
  add r5,#1
  cmp r5,#6
  blt saveKeys$

10、現在我們得到了新的按鍵。

mov r0,kbd
bl KeyboardPoll

11、最後我們要檢查 KeyboardOldDown 是否工作了。如果沒工作，那麼我們可能是斷開連接了。

teq r0,#0
bne getKeyboard$

return$:
pop {r4,r5,pc}
.unreq kbd

有了我們新的 KeyboardUpdate 方法，檢查輸入變得簡單，固定周期調用這個方法就行，而它甚至可以檢查鍵盤是否斷開連接，等等。這是一個有用的方法，因為我們實際的按鍵處理會根據條件不同而有所差別，所以能夠用一個函數調以它的原始方式獲取當前的輸入是可行的。下一個方法我們希望它是 KeyboardGetChar，簡單的返回下一個按下的按鈕的 ASCII 字元，或者如果沒有按鍵按下就返回 0。這可以擴展到支持如果它按下一個特定時間當做多次按下按鍵，也支持鎖定鍵和修飾鍵。

如果我們有一個 KeyWasDown 方法可以使這個方法有用起來，如果給定的掃描代碼不在 KeyboardOldDown 值中，它只返回 0，否則返回一個非零值。你可以自己嘗試一下。與往常一樣，可以在下載頁面找到解決方案。

7、查找表

KeyboardGetChar 方法如果寫得不好，可能會非常複雜。有 100 多種掃描碼，每種代碼都有不同的效果，這取決於 shift 鍵或其他修飾符的存在與否。並不是所有的鍵都可以轉換成一個字元。對於一些字元，多個鍵可以生成相同的字元。在有如此多可能性的情況下，一個有用的技巧是查找表。查找表與物理意義上的查找表非常相似，它是一個值及其結果的表。對於一些有限的函數，推導出答案的最簡單方法就是預先計算每個答案，然後通過檢索返回正確的答案。在這種情況下,我們可以在內存中建立一個序列的值，序列中第 n 個值就是掃描代碼 n 的 ASCII 字元代碼。這意味著如果一個鍵被按下，我們的方法只需要檢測到，然後從表中檢索它的值。此外，我們可以為當按住 shift 鍵時的值單獨創建一個表，這樣按下 shift 鍵就可以簡單地換個我們用的表。

在編程的許多領域，程序越大，速度越快。查找表很大，但是速度很快。有些問題可以通過查找表和普通函數的組合來解決。

在 .section .data 命令之後，複製下面的表：

.align 3
KeysNormal:
    .byte 0x0, 0x0, 0x0, 0x0, 'a', 'b', 'c', 'd'
    .byte 'e', 'f', 'g', 'h', 'i', 'j', 'k', 'l'
    .byte 'm', 'n', 'o', 'p', 'q', 'r', 's', 't'
    .byte 'u', 'v', 'w', 'x', 'y', 'z', '1', '2'
    .byte '3', '4', '5', '6', '7', '8', '9', '0'
    .byte 'n', 0x0, 'b', 't', ' ', '-', '=', '['
    .byte ']', '\', '#', ';', ''', '`', ',', '.'
    .byte '/', 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0
    .byte 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0
    .byte 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0
    .byte 0x0, 0x0, 0x0, 0x0, '/', '*', '-', '+'
    .byte 'n', '1', '2', '3', '4', '5', '6', '7'
    .byte '8', '9', '0', '.', '\', 0x0, 0x0, '='

.align 3
KeysShift:
    .byte 0x0, 0x0, 0x0, 0x0, 'A', 'B', 'C', 'D'
    .byte 'E', 'F', 'G', 'H', 'I', 'J', 'K', 'L'
    .byte 'M', 'N', 'O', 'P', 'Q', 'R', 'S', 'T'
    .byte 'U', 'V', 'W', 'X', 'Y', 'Z', '!', '"'
    .byte '£', '$', '%', '^', '&', '*', '(', ')'
    .byte 'n', 0x0, 'b', 't', ' ', '_', '+', '{'
    .byte &apos;}&apos;, &apos;|&apos;, &apos;~&apos;, &apos;:&apos;, &apos;@&apos;, &apos;¬&apos;, &apos;<&apos;, &apos;>&apos;
    .byte &apos;?&apos;, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0
    .byte 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0
    .byte 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0
    .byte 0x0, 0x0, 0x0, 0x0, &apos;/&apos;, &apos;*&apos;, &apos;-&apos;, &apos;+&apos;
    .byte &apos;n&apos;, &apos;1&apos;, &apos;2&apos;, &apos;3&apos;, &apos;4&apos;, &apos;5&apos;, &apos;6&apos;, &apos;7&apos;
    .byte &apos;8&apos;, &apos;9&apos;, &apos;0&apos;, &apos;.&apos;, &apos;|&apos;, 0x0, 0x0, &apos;=&apos;

這些表直接將前 104 個掃描碼映射到 ASCII 字元作為一個位元組表。我們還有一個單獨的表來描述 shift 鍵對這些掃描碼的影響。我使用 ASCII null 字元（0）表示所有沒有直接映射的 ASCII 鍵（例如功能鍵）。退格映射到 ASCII 退格字元（8 表示 b），enter 映射到 ASCII 新行字元（10 表示 n）， tab 映射到 ASCII 水平製表符（9 表示 t）。

.byte num 直接插入位元組常量 num 到文件。

.

大部分的彙編器和編譯器識別轉義序列；如 t 這樣的字元序列會插入該特殊字元。

KeyboardGetChar 方法需要做以下工作：

1. 檢查 KeyboardAddress 是否返回 0。如果是，則返回 0。
2. 調用 KeyboardGetKeyDown 最多 6 次。每次：
   1. 如果按鍵是 0，跳出循環。
   2. 調用 KeyWasDown。 如果返回是，處理下一個按鍵。
   3. 如果掃描碼超過 103，進入下一個按鍵。
   4. 調用 KeyboardGetModifiers
   5. 如果 shift 是被按著的，就載入 KeysShift 的地址，否則載入 KeysNormal 的地址。
   6. 從表中讀出 ASCII 碼值。
   7. 如果是 0，進行下一個按鍵，否則返回 ASCII 碼值並退出。
3. 返回 0。

試著自己實現。我的實現展示在下面：

1、簡單的檢查我們是否有鍵盤。

.globl KeyboardGetChar
KeyboardGetChar:
ldr r0,=KeyboardAddress
ldr r1,[r0]
teq r1,#0
moveq r0,#0
moveq pc,lr

2、r5 將會保存按鍵的索引，r4 保存鍵盤的地址。

push {r4,r5,r6,lr}
kbd .req r4
key .req r6
mov r4,r1
mov r5,#0
keyLoop$:
  mov r0,kbd
  mov r1,r5
  bl KeyboardGetKeyDown

2.1、 如果掃描碼是 0，它要麼意味著有錯，要麼說明沒有更多按鍵了。

teq r0,#0
beq keyLoopBreak$

2.2、如果按鍵已經按下了，那麼他就沒意義了，我們只想知道按下的按鍵。

mov key,r0
bl KeyWasDown
teq r0,#0
bne keyLoopContinue$

2.3、如果一個按鍵有個超過 104 的掃描碼，它將會超出我們的表，所以它是無關的按鍵。

cmp key,#104
bge keyLoopContinue$

2.4、我們需要知道修飾鍵來推斷字元。

mov r0,kbd
bl KeyboardGetModifiers

2.5、當將字元更改為其 shift 變體時，我們要同時檢測左 shift 鍵和右 shift 鍵。記住，tst 指令計算的是邏輯和，然後將其與 0 進行比較，所以當且僅當移位位都為 0 時，它才等於 0。

tst r0,#0b00100010
ldreq r0,=KeysNormal
ldrne r0,=KeysShift

2.6、現在我們可以從查找表載入按鍵了。

ldrb r0,[r0,key]

2.7、如果查找碼包含一個 0，我們必須繼續。為了繼續，我們要增加索引，並檢查是否到 6 次了。

teq r0,#0
bne keyboardGetCharReturn$
keyLoopContinue$:
add r5,#1
cmp r5,#6
blt keyLoop$

3、在這裡我們返回我們的按鍵，如果我們到達 keyLoopBreak$ ，然後我們就知道這裡沒有按鍵被握住，所以返回 0。

keyLoopBreak$:
mov r0,#0
keyboardGetCharReturn$:
pop {r4,r5,r6,pc}
.unreq kbd
.unreq key

8、記事本操作系統

現在我們有了 KeyboardGetChar 方法，可以創建一個操作系統，只列印出用戶對著屏幕所寫的內容。為了簡單起見，我們將忽略所有非常規的鍵。在 main.s，刪除 bl SetGraphicsAddress 之後的所有代碼。調用 UsbInitialise，將 r4 和 r5 設置為 0，然後循環執行以下命令:

1. 調用 KeyboardUpdate
2. 調用 KeyboardGetChar
3. 如果返回 0，跳轉到步驟 1
4. 複製 r4 和 r5 到 r1 和 r2 ，然後調用 DrawCharacter
5. 把 r0 加到 r4
6. 如果 r4 是 1024，將 r1 加到 r5，然後設置 r4 為 0。
7. 如果 r5 是 768，設置 r5 為0
8. 跳轉到步驟 1

現在編譯，然後在樹莓派上測試。你幾乎可以立即開始在屏幕上輸入文本。如果沒有工作，請參閱我們的故障排除頁面。

當它工作時，祝賀你，你已經實現了與計算機的介面。現在你應該開始意識到，你幾乎已經擁有了一個原始的操作系統。現在，你可以與計算機交互、發出命令，並在屏幕上接收反饋。在下一篇教程輸入02中，我們將研究如何生成一個全文本終端，用戶在其中輸入命令，然後計算機執行這些命令。

via: https://www.cl.cam.ac.uk/projects/raspberrypi/tutorials/os/input01.html

作者：Alex Chadwick 選題：lujun9972 譯者：ezio 校對：wxy

本文由 LCTT 原創編譯，Linux中國 榮譽推出

本文轉載來自 Linux 中國: https://github.com/Linux-CN/archive